PlotSquared/Core/build.gradle

dependencies {
    testCompile 'junit:junit:4.12'
    compile 'org.yaml:snakeyaml:1.23'
    compile 'com.google.code.gson:gson:2.8.5'
    compileOnly 'org.projectlombok:lombok:1.18.4'
}
sourceCompatibility = 1.8
targetCompatibility = 1.8


processResources {
    from('src/main/resources') {
        include 'plugin.properties'
        expand(
                version: "${project.parent.version}",
                name: project.parent.name,
        )
    }
}

jar.archiveName = "plotsquared-api-${project.parent.version}.jar"
jar.destinationDir = file '../mvn/com/plotsquared/plotsquared-api/' + project.parent.version
task createPom {
    doLast {
        pom {
            project {
                groupId 'com.github.intellectualsites.plotsquared'
                artifactId 'Plotsquared'
                version project.parent.version
            }
        }.writeTo("../mvn/com/github/intellectualsites/plotsquared/Plotsquared-Api/${project.parent.version}/Plotsquared-Api-${project.parent.version}.pom")
        pom {
            project {
                groupId 'com.github.intellectualsites.plotsquared'
                artifactId 'Plotsquared'
                version 'latest'
            }
        }.writeTo("../mvn/com/github/intellectualsites/plotsquared/Plotsquared-Api/latest/Plotsquared-Api-latest.pom")
    }
}

task copyFiles {
    doLast {
        copy {
            from "../mvn/com/plotsquared/plotsquared-api/${project.parent.version}/"
            into '../mvn/com/plotsquared/plotsquared-api/latest/'
            include('*.jar')
            rename("plotsquared-api-${project.parent.version}.jar", 'plotsquared-api-latest.jar')
        }
    }
}

build.finalizedBy(copyFiles)
copyFiles.dependsOn(createPom)