PlotSquared/Core/build.gradle

dependencies {
    testCompile 'junit:junit:4.12'
    compile 'org.yaml:snakeyaml:1.16'
    compile 'com.google.code.gson:gson:2.2.4'
    compileOnly 'org.projectlombok:lombok:1.18.4'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8


processResources {
    from('src/main/resources') {
        include 'plugin.properties'
        expand(
                version: "${project.parent.version}",
                name: project.parent.name,
        )
    }
}

jar.archiveName = "plotsquared-api-${project.parent.version}.jar"
jar.destinationDir = file '../mvn/com/plotsquared/plotsquared-api/' + project.parent.version
task createPom << {
    pom {
        project {
            groupId 'com.plotsquared'
            artifactId 'plotsquared-api'
            version project.parent.version
        }
    }.writeTo("../mvn/com/plotsquared/plotsquared-api/${project.parent.version}/plotsquared-api-${project.parent.version}.pom")
    pom {
        project {
            groupId 'com.plotsquared'
            artifactId 'plotsquared-api'
            version 'latest'
        }
    }.writeTo("../mvn/com/plotsquared/plotsquared-api/latest/plotsquared-api-latest.pom")
}

task copyFiles {
    doLast {
        copy {
            from "../mvn/com/plotsquared/plotsquared-api/${project.parent.version}/"
            into '../mvn/com/plotsquared/plotsquared-api/latest/'
            include('*.jar')
            rename("plotsquared-api-${project.parent.version}.jar", 'plotsquared-api-latest.jar')
        }
    }
}

build.finalizedBy(copyFiles)
copyFiles.dependsOn(createPom)