buildscript {
    repositories {
        jcenter()
        mavenLocal()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven { url = "http://repo.minecrell.net/releases" }
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'gradle.plugin.net.minecrell:vanillagradle:2.2-6'
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

apply plugin: 'net.minecrell.vanillagradle.server'

dependencies {
    compile project(':Core')
    compile 'org.spongepowered:spongeapi:7.1.0-SNAPSHOT'
    compile 'net.minecrell.mcstats:statslite-sponge:0.2.2'

}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    maven {
        name = 'minecrell'
        url = 'http://repo.minecrell.net/releases'
    }
    maven {
        name = 'forge'
        url = 'http://files.minecraftforge.net/maven'
    }
    maven {
        name = "Sponge"
        url = "https://repo.spongepowered.org/maven"
    }
}
minecraft {
    version = "1.12.2"
    mappings = "snapshot_20171022"
    runDir = 'run'
}

project.archivesBaseName = "${project.archivesBaseName}-mc${minecraft.version}"

processResources {
    from(sourceSets.main.resources.srcDirs) {
        expand 'version': project.version,
                'mcVersion': project.minecraft.version
    }
}
shadowJar {
    dependencies {
        include(dependency(':Core'))
        include dependency('net.minecrell.mcstats:statslite-sponge')
    }
    relocate 'net.minecrell.mcstats', 'com.plotsquared.util.mcstats'
    archiveName = "${parent.name}-${project.name}-${parent.version}.jar"
    destinationDir = file '../target'
}
shadowJar.doLast {
    task ->
        ant.checksum file: task.archivePath
}

reobf {
    shadowJar {
        mappingType = 'SEARGE'
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
}

build.dependsOn(shadowJar)
